1.2.2 Gemiddeld aantal ingezette fte personeel niet in loondienst (PNIL) met een zorgfunctie.

Concepten

• Gewerkte periode
• Inhuurovereenkomst
• Uitzendovereenkomst
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• gedefinieerd door
• heeft deel
• heeft eigenschap of kenmerk
• heeft eigenschapswaarde
• heeft opdrachtnemer

Eigenschappen

• einddatum
• heeft datawaarde
• heeftBeginTijd
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: NZA Wmg 1.2.2
2# Parameters: ?jaar
3# Ontologie: versie 3.0
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT
12    (COALESCE(ROUND(SUM(?inzet_fte)/COUNT(?maand)), 0) AS ?Teller)
13    ("Niet van toepassing" AS ?Noemer)
14    (COALESCE(ROUND(SUM(?inzet_fte)/COUNT(?maand)), 0) AS ?Indicator_FTE36)
15WHERE {
16    SELECT 
17        ?maand
18        (SUM(?inzet_uren)/141 AS ?inzet_fte)
19    WHERE {
20        # BIND(2024 AS ?jaar) .  # Parameter
21
22        BIND(STRDT(CONCAT(STR(?jaar), "-01-01"), xsd:date) AS ?start_peildatum) .
23        BIND(?start_peildatum + "P1Y"^^xsd:duration - "P1D"^^xsd:duration AS ?eind_peildatum) .
24
25        VALUES ?type_overeenkomst 
26        { 
27            onz-pers:InhuurOvereenkomst
28            onz-pers:UitzendOvereenkomst
29        }
30        ?overeenkomst 
31            a ?type_overeenkomst ;
32            onz-pers:heeftOpdrachtnemer ?persoon ;
33            onz-g:hasPart ?overeenkomst_afspraak .
34        ?overeenkomst_afspraak
35            a onz-pers:WerkOvereenkomstAfspraak ;
36            onz-g:isAbout/a onz-pers:ZorgverlenerFunctie ;
37            onz-g:startDatum ?start_afspraak .
38        OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
39        FILTER(?start_afspraak <= ?eind_peildatum && ((?eind_afspraak >= ?start_peildatum) || (!BOUND(?eind_afspraak))))
40
41        ?inzet
42            a onz-pers:GewerktePeriode ;
43            onz-g:definedBy ?overeenkomst ;
44            onz-g:hasBeginTimeStamp ?start_inzet_datetime ;
45            onz-g:hasQuality/onz-g:hasQualityValue/onz-g:hasDataValue ?inzet_uren .
46        BIND(STRDT(SUBSTR(STR(?start_inzet_datetime), 1, 10), xsd:date) AS ?start_inzet)
47        FILTER(?start_inzet >= ?start_peildatum && ?start_inzet <= ?eind_peildatum)
48        FILTER(?start_inzet >= ?start_afspraak && (?start_inzet <= ?eind_afspraak || !BOUND(?eind_afspraak)))
49        BIND(MONTH(?start_inzet) AS ?maand)
50    }
51    GROUP BY ?maand
52}